Any mappers / scripters alive and/or active?

[DaveTheBlaze]

Thanks for replying Crusha!

If you wanted to get it to work with regular VehicleFactories, you could have a script that takes care of spawning the UltimateRadarVehicleLRIs itself for the relevant vehicles. You would need to constantly iterate some list on basically every Tick to find relevant vehicles and also keep track of whether they already have an LRI.

As if I would be able to code something like that xD
I only know basic C++ stuff, not sufficient enough to code something like that.

If you are only interested in vehicles driven by players (since it's a racing mode), you could iterate through Level.ControllerList, check the Pawn of each controller and see if that is a vehicle or has a driven vehicle. That would seem better than iterating DynamicActors with a constraint on the Vehicle class, which could given even worse performance. You would then either need to hardcode the settings for the radar map texture, etc. or make them configurable in your actor for each vehicle class that is going to be used. If the vehicle associated with the LRI gets destroyed, the LRI will destroy itself shortly after (via the BaseChanged() event).

Is there an easy way to make it work properly? I don't have any idea where to start.
But the quote above means that if a player leaves a car, the car is no longer be tracked. Not a deal-breaker but it would be nice to have the cars tracked even without anyone driving it.

I could try to make it work better in a future release of UMTv2, but for now just overriding the initialization in a subclass seems the easiest way to go.

That would be awesome .

So what do you think? Is scripting a new actor worth the hassle? Or should I rather try to make the TeamRadar Mutator working?
Since Corona I'm just bored, so I've got the time and energy to work on at least something ^^.
Are you up to help me out? Otherwise I'm probably lost and won't use the UltimateRadar at all.

[Crusha K. Rool]

But the quote above means that if a player leaves a car, the car is no longer be tracked. Not a deal-breaker but it would be nice to have the cars tracked even without anyone driving it.

It would mean that it only gets tracked once someone enters it, but remain tracked after they leave it.

I could probably try to whip up some code to do it by next weekend and let you include it via MyLevel. I'd then include it into the official release in the future, but that might still be some time off. At some point I'll start uploading the current progress to Github and also use it to keep track of issues. But I need to clean up the package structure for that first.

[DaveTheBlaze]

It would mean that it only gets tracked once someone enters it, but remain tracked after they leave it.

ah ok I see
Well, better than nothing. But there is no way of tracking vehicles as well that weren't entered by a player before?
Because there are vehicles spread over the map which will be entered during the match (or not) but it would be nice to see where they are located on the map (e.g. Hellbenders, Raptors, Tanks, Scorps).

I could probably try to whip up some code to do it by next weekend and let you include it via MyLevel. I'd then include it into the official release in the future, but that might still be some time off. At some point I'll start uploading the current progress to Github and also use it to keep track of issues. But I need to clean up the package structure for that first.

wow thanks a lot, didn't think anyone would still improve code for a game that old .
If you manage to improve the code in order for the tracking to work for any VehicleFactory you definitely earn my gratitude and a special thanks place on my map as well .

[Crusha K. Rool]

Here is some script code. I did not have time to actually test if it functionally works (let alone whether it requires special handling for network replication). I just made sure that it does not have any compile errors. You can use it in addition to the aforementioned subclass of the UltimateRadarMap actor. (I think you can/need to leave the Default Properties block away when adding it directly in UnrealEd.)

Code: Select all

//-----------------------------------------------------------------------------
// Ultimate Radar Map Dynamic Vehicle Tracker
// © 2020 by D. 'Crusha K. Rool' I.
//
// Workaround to enable vehicle tracking on the Ultimate Radar Map in scenarios
// where you can't use custom placed UltimateVehicleFactories.
// This approach has a lot of performance overhead and only starts tracking vehicles
// upon driving them, so using the factories is still preferable whenever possible.
//
// Place this actor in the map along with the UltimateRadarMap actor and configure
// in the list for which vehicle classes (including subclasses) you want to use
// which radar tracking.
//-----------------------------------------------------------------------------
class UltimateRadarMapDynamicVehicleTracker extends Info
    placeable
    DependsOn(UltimateRadarVehicleLRI);

struct _VehicleRadarProperties
{
  var() class<Vehicle>   VehicleClass;   // Vehicle class to which this tracking applies.
  var() bool   bRadarVisibleToDriver; // Should the vehicle be shown on the radar to it's driver?
  var() bool   bRadarNeutralWhenEmpty;// If true, the vehicle is drawn with white team color when it's left.
  var() bool   bRadarHideWhenEmpty;   // If true, the vehicle is not drawn when it's empty.

  var() UltimateRadarVehicleLRI.ERadarVehicleVisibility RadarVehicleVisibility;

  var() float  RadarOwnerUpdateTime; // How many seconds have to pass before the location of vehicle is updated for the owning team.
  var() float  RadarEnemyUpdateTime; // Same as above, just for enemies.
  var() bool   bRadarFadeWithOwnerUpdateTime; // If True, the icon on the radar map will interpolate between opaque and translucent as time passes between location updates on the radar.
  var() bool   bRadarFadeWithEnemyUpdateTime; // If False, the icon will always stay fully opaque.

  var() Material RadarTexture;       // This image will represent the vehicle on the Radar.
                                     // The texture shouldn't have any other colours than white and transparent, otherwise you will get an ugly dark square.
  var() float  RadarTextureScale;    // The image will be scaled by this factor.
  var() int    RadarTextureRotationOffset;
};

// Here you can define which vehicle classes will automatically get tracked on the radar and which properties the tracking uses.
var() array<_VehicleRadarProperties>  VehicleRadarPropertyList;

var array<Vehicle> CheckedVehicles;

simulated event Tick(float DeltaTime)
{
    local Controller C;
    local Vehicle V;

    for ( C = Level.ControllerList; C != none; C = C.nextController )
    {
        if ( Vehicle( C.Pawn ) != none )
        {
            V = Vehicle( C.Pawn );
        }
        else if ( C.Pawn != none && C.Pawn.DrivenVehicle != none )
        {
            V = C.Pawn.DrivenVehicle;
        }
        if ( V != none )
        {
            MaybeTrackVehicle( V );
        }
    }
}

function MaybeTrackVehicle( Vehicle V )
{
    local int i;
    local bool AlreadyTracked;
    local UltimateRadarVehicleLRI NewVehicleLRI;

    for ( i = 0; i < CheckedVehicles.Length; i++ )
    {
        if ( V == CheckedVehicles[ i ] )
        {
            AlreadyTracked = true;
            break;
        }
    }

    if ( !AlreadyTracked )
    {
        // Find the first properties set from the list that has a matching vehicle class.
        for ( i = 0; i < VehicleRadarPropertyList.Length; i++ )
        {
            if ( ClassIsChildOf( V.class, VehicleRadarPropertyList[ i ].VehicleClass ) )
            {
                break;
            }
        }

        // if i is not less than the length of the array, we didn't find a match.
        if ( i < VehicleRadarPropertyList.Length )
        {
            NewVehicleLRI = Spawn( class'UltimateRadarVehicleLRI' );

            NewVehicleLRI.TrackedVehicle = V;
            NewVehicleLRI.OldOwnerTeam = V.Team;
            NewVehicleLRI.RadarMaterial = VehicleRadarPropertyList[ i ].RadarTexture;
            NewVehicleLRI.RadarTextureScale = VehicleRadarPropertyList[ i ].RadarTextureScale;
            NewVehicleLRI.RadarTextureRotationOffset = VehicleRadarPropertyList[ i ].RadarTextureRotationOffset;
            NewVehicleLRI.RadarVehicleVisibility = VehicleRadarPropertyList[ i ].RadarVehicleVisibility;
            NewVehicleLRI.bRadarVisibleToDriver = VehicleRadarPropertyList[ i ].bRadarVisibleToDriver;
            NewVehicleLRI.bRadarNeutralWhenEmpty = VehicleRadarPropertyList[ i ].bRadarNeutralWhenEmpty;
            NewVehicleLRI.bRadarHideWhenEmpty = VehicleRadarPropertyList[ i ].bRadarHideWhenEmpty;
            NewVehicleLRI.RadarOwnerUpdateTime = VehicleRadarPropertyList[ i ].RadarOwnerUpdateTime;
            NewVehicleLRI.RadarEnemyUpdateTime = VehicleRadarPropertyList[ i ].RadarEnemyUpdateTime;
            NewVehicleLRI.bRadarFadeWithOwnerUpdateTime = VehicleRadarPropertyList[ i ].bRadarFadeWithOwnerUpdateTime;
            NewVehicleLRI.bRadarFadeWithEnemyUpdateTime = VehicleRadarPropertyList[ i ].bRadarFadeWithEnemyUpdateTime;
            NewVehicleLRI.SetBase( V );
        }
        CheckedVehicles[ CheckedVehicles.Length ] = V;
    }

}

DefaultProperties
{

}

[DaveTheBlaze]

Here is some script code.

Thanks a lot for the effort!

You can use it in addition to the aforementioned subclass of the UltimateRadarMap actor.

You mean this aforementioned actor?

"to make a subclass of UltimateRadarMap in unrealed and override the simulated event PostBeginPlay() who is currently checking for UltimateVCTFFactory to check for AsVehicleFactory instead if it's possible, so you can use the right factory in your map without too many changes."

-> if yes: didn't work for me
-> if no: pls elaborate on what actor subclass you mean

Greets, Dave

[Crusha K. Rool]

Yeah, that's what I meant. Bummer. Might take another look next weekend to see why it's not working.

[DaveTheBlaze]

So, any results yet?

[Crusha K. Rool]

I was able to get it to work in ONS (see the attached screenshot). Did not try out other modes yet.

For ONS, I had to make a minor adjustment to the code above to also make it create the HUD Overlay for the radar. That's something that my actors usually take care of themselves, since the UltimateRadarMap actor is obsolete in ONS. However, the rest of the code for the dynamic adding was working just fine - no adjustment was needed there to get it to work, so it should also work in other modes in theory.

Just to make sure: did you assign some vehicle classes to track when you added the actor to your map? Did you set up proper textures to track and change their texture scale to something non-zero? Maybe it's best if you posted a screenshot of your actor's properties window.

If there is no obvious mistake there, I'll take a look at other modes.

[DaveTheBlaze]

It still doesn't work for Assault/Racing but I don't know why.
It looks like this:

RadarMap.jpg (448.42 KiB) Viewed 18913 times

These are the 3 actors I'm using:

UltimateRadarMapDynamic_Actor.jpg (126.6 KiB) Viewed 18913 times

UltimateRadarMap_Actor.jpg (128.27 KiB) Viewed 18913 times

UltimateRadarMapMarker.jpg (133.63 KiB) Viewed 18913 times

And just to ensure nothing is missing, here the ASTaggedVehicleFactory with the edited 'VehicleTypeTag':

ASTaggedVehicleFactory_Actor.jpg (100.13 KiB) Viewed 18910 times

Adding the class 'Onslaught.ONSPRV' to the 'VehicleRadarPropertyList' inside the 'UltimateRadarMapDynamicVehicleTracker' doesn't make a difference. Neither does changing the texture scale.
I'm using the original 'UltimateRadarMap' actor refering to VCTF Factories, since my edit didn't compile right.

simulated event PostBeginPlay()
{
local UltimateVCTFFactory UVF;
local int i;

if (bDisabled)
{
return;
}

// UltimateRadarMapPanel.ClassName = string(class'UT2K4Tab_UltimateRadarMap');

foreach AllActors(class'UltimateVCTFFactory', UVF)
{
if (bHasRadarVehicles)
break;

for (i = 0; i < UVF.VehicleList.Length; i++)
{
if (UVF.VehicleList[i].bTrackVehicleOnRadar)
{
bHasRadarVehicles = True;
break;
}
}
}

if (Level.NetMode != NM_DedicatedServer) // don't spawn the overlay and menu panel on dedicated servers
{
Enable ('Tick');
}
else
{
Disable ('Tick');
}
}

//=============================================================================

[DaveTheBlaze]

PS (max. amount of attached pictures within one thread reached xD):

Crusha.jpg (372.76 KiB) Viewed 18894 times